Sintaxe
DAX
Formato.Escala ( valor [, decimais] )Parâmetros
- valorNUMERICObrigatório
Valor que será exibido; na medida, SELECTEDMEASURE ().
DAXSELECTEDMEASURE ()- decimaisINT64Opcional
Casas decimais. Padrão 1.
DAX0
Tipo de retorno
Texto
Exemplos
DAX
-- Medida Total de Vendas → Formato: Dinâmico → expressão:
Formato.Escala ( SELECTEDMEASURE () )
-- Com 0 casas decimais:
Formato.Escala ( SELECTEDMEASURE (), 0 )Código completo
DAX
DEFINE
/// Cadeia de formato com escala automática (mil, mi, bi).
/// Use no formato dinâmico da medida: Formato.Escala ( SELECTEDMEASURE () ).
/// @param {NUMERIC} valor - Valor que será exibido
/// @param {INT64} [decimais] - Casas decimais; padrão 1
/// @returns Cadeia de formato (texto) para a propriedade de formato
FUNCTION Formato.Escala =
( valor : NUMERIC, decimais : INT64 = 1 ) =>
VAR _abs = ABS ( valor )
VAR _casas = IF ( decimais > 0, "." & REPT ( "0", decimais ), "" )
RETURN
SWITCH (
TRUE (),
ISBLANK ( valor ), "#,0",
ROUND ( _abs / 1000000000, decimais ) >= 1, "#,0,,," & _casas & """ bi""",
ROUND ( _abs / 1000000, decimais ) >= 1, "#,0,," & _casas & """ mi""",
ROUND ( _abs / 1000, decimais ) >= 1, "#,0," & _casas & """ mil""",
"#,0" & _casas
)
EVALUATE
ADDCOLUMNS (
{ 950, 12345, 999950, 4567890, 1234567890 },
"Formato", Formato.Escala ( [Value] ),
"Exibido", FORMAT ( [Value], Formato.Escala ( [Value] ) )
)
-- Esperado em modelo pt-BR: 950,0 | 12,3 mil | 1,0 mi | 4,6 mi | 1,2 biMais informações
- Fonte
- Paulo André Jesus — OfficeTuning
- Versão
- 1.0.0